**Инструкция по внедрению библиотеки статистики AdmanClip.**

Библиотека учета статистики во flash-баннерах (AdmanClip) представляет собой самодостаточное flash-приложение (swf-файл), написанное на ActionScript 3.

Библиотека расположена по адресу <http://rs.mail.ru/vp/admanclip.swf>.

Приложение, внедряющее библиотеку должно быть написано с использованием ActionScript 3.

1. Загрузка библиотеки.

Прежде чем использовать библиотеку, её необходимо сначала загрузить в приложение.

Перед загрузкой библиотеки необходимо разрешить доступ к приложению с домена библиотеки:

Security.allowDomain("rs.mail.ru");

Далее загружаем саму библиотеку. Все примеры кода приведены для первого кадра основной шкалы. Рекомендуется скрывать контент приложения до завершения загрузки:

var loader:Loader;

var adman:Object;

…..

stop();

buttonMode=true;

visible=false;

loader=new Loader();

loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadCompleteHandler);

loader.load(new URLRequest(root.loaderInfo.parameters.admanUrl));

function loadCompleteHandler(e:Event):void{

 adman=loader.content;

 visible=true;

 }

1. Инициализация библиотеки.

После загрузки библиотеки её надо инициализировать, вызвав метод init и передав в него ссылку на основую временную шкалу баннера:

adman.init(this);

Во время отладки баннера вторым параметром можно передать ссылку на видео.

1. Работа с библиотекой.

После инициализации надо подписаться на события от библиотеки и дать команду запустить воспроизведение. Все возможные события и команды описаны ниже.

adman.addEventListener("videoCompleted",videoCompletedHandler);

adman.addEventListener("admanClipMessage",messageHandler);

adman.setOutput(video);

adman.play();

function videoCompletedHandler(e:Event):void{

 adman.repeat();

}

function messageHandler(e:Object):void{

 trace(e[“message”]);

}

В данном примере кода, видео будет проигрываться циклично.

1. Методы библиотеки

Публичные методы:

init(swfRoot:InteractiveObject, src:String = null). Данный метод инициализирует плагин. Все последующие обращения к методам плагина можно производить только после вызова этого метода. При попытке обратиться к методу плагина до вызова этого метода, будет сгенерирована ошибка.
Параметры:
swfRoot - ссылка на document-class баннера или, проще говоря, на главную временную шкалу.

setOutput(video:Video):void. Устанавливает объект Video, который будет использоваться для отображения потока видео.

play():void. Запускает воспроизведение видео потока.

pause(needStat:Boolean=true):void. Приостанавливает воспроизведение. Второй параметр указывает, следует ли отправлять статистику на это действие (Например, если баннер по умолчанию на паузе, то на это действие статистику отправлять не надо для первого раза).

resume(needStat:Boolean=true):void. Возобновляет воспроизведение. Второй параметр указывает, следует ли отправлять статистику на это действие (Например, если баннер по умолчанию был на паузе, то на это действие статистику отправлять не надо для первого раза).

repeat():void. Начинает воспроизведение с начала.

stop():void. Останавливает воспроизведение.

setVolume(value:Number, needStat:Boolean=true):void. Устанавливает громкость звука. Второй параметр указывает, следует ли отправлять статистику на это действие (Например, если для баннера звук по умолчанию выключен, то на это действие статистику отправлять не надо для первого раза).

click(link1):void. Осуществляет переход пользователя на страницу рекламодателя.

destroy():void. При вызове этого метода происходит остановка показа и удаление всех данных, слушателей и других объектов, которые могут помешать сборщику мусора.

Публичные свойства:

volume. Устанавливает громкость звука.

bufferTime. Устанавливает размер буффера (Аналогично свойству bufferTime объекта NetStream).

stream. Только для чтения. Ссылка на объект NetStream текущего потока.

1. События библиотеки.

videoCompleted  - отправляется при завершении воспроизведения.

admanMessage - отправляется во всем цикле работы плагина, содержит поле message, в которое записывается различная информация. Фактически trace.

1. Пример использования

import flash.display.Loader;

import flash.events.Event;

import flash.net.URLRequest;

import flash.events.MouseEvent;

stop();

visible=false;

buttonMode=true;

var adman:Object;

var link:String=loaderInfo.parameters.link1;

var isPaused:Boolean;

var loader:Loader=new Loader();

loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadCompleteHandler);

loader.load(new URLRequest(root.loaderInfo.parameters.admanUrl));

function loadCompleteHandler(e:Event):void{

 adman=loader.content;

 visible=true;

 start();

}

function start():void{

 adman.init(this);

 adman.volume=0.5;

 adman.bufferTime=5;

 adman.setOutput(video);

 adman.addEventListener("videoCompleted",videoCompletedHandler);

 adman.addEventListener("admanClipMessage",messageHandler);

 adman.play();

}

mcPlayPause.addEventListener(MouseEvent.CLICK, playbackHandler);

function playbackHandler(e:MouseEvent):void{

 mcPlayPause.nextFrame();

 if(isPaused){

 isPaused=false;

 adman.resume();

 }

 else{

 isPaused=true;

 adman.pause();

 }

}

bg.addEventListener(MouseEvent.CLICK, clickHandler);

function clickHandler(e:MouseEvent):void{

 adman.click(link);

}

function videoCompletedHandler(e:Event):void{

 setTimeout(function(){adman.repeat();},3000);

}

function messageHandler(e:Object):void{

 trace(e.message);

}

1. Включение звука по наведению.

События наведения и увода мыши swf файл должен получать от javascript и не должен использовать для этого свои методы.

Пример кода:

AS3

ExternalInterface.addCallback("mouseOver", overHandler);

ExternalInterface.addCallback("mouseOut", outHandler);

function overHandler(){

trace("mouse over");

}

function outHandler(){

trace("mouse out");

}

AS2

ExternalInterface.addCallback("mouseOver", function(){ trace("mouseOver")};

ExternalInterface.addCallback("mouseOut", function(){trace("mouseOut")};

Не забыть так же разрешить доступ извне

as3

Security.allowDomain("\*");

as2

System.security.allowDomain("\*");